image := 'cr.d464.sh/fct-drive:latest'
remote := 'prod'

_default:
    just --list

build:
    cargo build --release --target-dir target/

dev:
    demon run tinyauth ./tinyauth.sh
    cd frontend && demon run dev -- npm run dev

stop:
    demon stop tinyauth
    demon stop dev

logs:
    demon cat tinyauth | tail -n 100
    demon cat dev | tail -n 100

tail:
    demon tail -f dev

deploy-tinyauth:
    #!/usr/bin/env bash 
    ssh {{remote}} <<EOF
        podman stop fctdrive_tinyauth
        podman rm fctdrive_tinyauth
        podman run -d --network host \
            --name fctdrive_tinyauth \
            -e PORT=3001 \
            -e APP_URL="https://auth.fctdrive.xyz" \
            -e SECRET=$(openssl rand -hex 16) \
            -e OAUTH_AUTO_REDIRECT="google" \
            -e GOOGLE_CLIENT_ID=$(pass google.com/fct-drive/oauth-client-id) \
            -e GOOGLE_CLIENT_SECRET=$(pass google.com/fct-drive/oauth-client-secret) \
            ghcr.io/steveiliop56/tinyauth:v3
    EOF

deploy-frontend: push-container
    #!/usr/bin/env bash
    # sudo mount.cifs -o uid=1000,gid=1000,username=u484453 //u484453.your-storagebox.de/backup fct-drive
    ssh {{remote}} <<EOF
        podman pull {{image}}
        podman rm -f fctdrive_frontend
        podman run -td --network host \
            --name fctdrive_frontend \
            -e PORT=3000 \
            -e FCTDRIVE_PATH=/data \
            -e TINYAUTH_ENDPOINT="http://127.0.0.1:3001" \
            -e TINYAUTH_PUBLIC_ENDPOINT="https://auth.fctdrive.xyz" \
            -v /home/diogo464/fct-drive:/data \
            --pull=never \
            {{image}}
    EOF

build-container: build
    cd frontend && npm run build
    podman build -t {{image}} .

push-container: build-container
    podman push {{image}}